Скрипт выброса игрока из воздушного транспорта, со случайной точкой парашютирования.

Данный скрипт взят из миссии Altis On Fire от MeatballCB .
И совсем немного отредактирован мной в 1 и 24 строке.

// AirDrop Script - By Meatball

// Отключаем урон игроку
player allowdamage false;

// Затемняем экран
0 cutText ["","BLACK FADED"];

// Выбрасываем игрока из транспорта
moveout player;

// Записываем его снаряжение
_gear = [];
_backpack = backpack player;
_backpack2 = unitbackpack player;
_backpack_items = getItemCargo (unitBackpack player);
_backpack_weap = getWeaponCargo (unitBackpack player);
_backpack_mags = getMagazineCargo (unitBackpack player);

_gear =	[_backpack_items, _backpack_weap, _backpack_mags];

// Убираем рюкзак и добавляем парашют.
3 fadeSound 0.15;
removeBackpack player;
sleep 1.5;
player addBackpack "B_Parachute";
deleteVehicle _backpack2;

// Выбираем случайную позицию для выброса игрока из массива координат
_droppoints = selectRandom [[8318.69,14883.9,2500], [10271.4,14399,2500], [9362.18,14810.3,2500]];

player setPos _droppoints;

// Пускаем текст для объяснения произошедшего
if(didJIP) then {
["<t size='1.1'>" + "Ваш вертолёт подбили ракетой запущенной с земли, и он начал сильно вращаться. Вы видите как члены отряда выпадают в двреи вертолёта." + "</t>",0.03,0.3,3,2,0,3012] spawn bis_fnc_dynamicText;
3 cutText ["","BLACK FADED"];
sleep 1;
playMusic "LeadTrack01a_F_EPB";
sleep 6;
["<t size='1.1'>" + "Вы теряете равновесие.  И вас жёстко выбрасывает в двери." + "</t>",0.03,0.3,3,2,0,3012] spawn bis_fnc_dynamicText;
3 cutText ["","BLACK FADED"];
sleep 7;
["<t size='1.1'>" + "Вы пытаетесь сгрупироваться.  Но вы теряете контроль и вас швыряет куда-то в сторону..." + "</t>",0.03,0.3,3,2,0,3012] spawn bis_fnc_dynamicText;
3 cutText ["","BLACK FADED"];
sleep 7;	
//playSound ["heliFlyby",false];
titleText ["", "BLACK IN",2];	
player setdamage 0.2;
sleep 7;
["<t size='1.3'>" + "Хрен его знает где..." + "</t>",0.02,0.4,3,2,0,3012] spawn bis_fnc_dynamicText;
0 fadeSound 1;
  } else {
["<t size='1.1'>" + "Ваш вертолёт подбили ракетой запущенной с земли, и он начал сильно вращаться. Вы видите как члены отряда выпадают в двреи вертолёта." + "</t>",0.03,0.3,3,2,0,3012] spawn bis_fnc_dynamicText;
3 cutText ["","BLACK FADED"];
sleep 1;
playMusic "LeadTrack01a_F_EPB";
sleep 6;
["<t size='1.1'>" + "Вы теряете равновесие.  И вас жёстко выбрасывает в двери." + "</t>",0.03,0.3,3,2,0,3012] spawn bis_fnc_dynamicText;
3 cutText ["","BLACK FADED"];
sleep 7;
["<t size='1.1'>" + "Вы пытаетесь сгрупироваться.  Но вы теряете контроль и вас швыряет куда-то в сторону..." + "</t>",0.03,0.3,3,2,0,3012] spawn bis_fnc_dynamicText;
3 cutText ["","BLACK FADED"];
sleep 7;	
//playSound ["heliFlyby",false];
titleText ["", "BLACK IN",2];	
player setdamage 0.2;
sleep 6;
["<t size='1.3'>" + "Хрен его знает где..." + "</t>",0.02,0.4,3,2,0,3012] spawn bis_fnc_dynamicText;
0 fadeSound 1;
};

// Ждём пока игрок коснётся земли
waitUntil {isTouchingGround player};
sleep 2;

// Делаем его вновь уязвимым
player allowdamage true;

// Убираем парашют
removeBackpack player;
if (_backpack == "") exitWith{};

// Возвращаем ему рюкзак который был
player addbackpack _backpack;

waitUntil {(backpack player) == _backpack};
clearWeaponCargoGlobal (backpackContainer player);
clearMagazineCargoGlobal (backpackContainer player);
clearItemCargoGlobal (backpackContainer player);  

// Возвращаем предметы из массива _gear
if (count ((_gear select 1) select 0) > 0) then	{
    for "_i" from 0 to (count ((_gear select 1) select 0) - 1) do
    {  
    (unitBackpack player) addweaponCargoGlobal [((_gear select 1) select 0) select _i,((_gear select 1) select 1) select _i];
    };
};
if (count ((_gear select 2) select 0) > 0) then	{
    for "_i" from 0 to (count ((_gear select 2) select 0) - 1) do
    { 
      (unitBackpack player) addMagazineCargoGlobal [((_gear select 2) select 0) select _i,((_gear select 2) select 1) select _i];
    };
};
if (count ((_gear select 0) select 0) > 0) then	{
    for "_i" from 0 to (count ((_gear select 0) select 0) - 1) do
    {  
      (unitBackpack player) addItemCargoGlobal [((_gear select 0) select 0) select _i,((_gear select 0) select 1) select _i];
    };
};

Если же что-то непонятно, то можно спросить / уточнить в нашем Discord канале